{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";

    flake-utils.url = "github:numtide/flake-utils";

    nixvim = {
      url = "github:nix-community/nixvim";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    hml = {
      url = "github:mawkler/hml.nvim";
      flake = false;
    };

    typst-preview = {
      url = "github:al-kot/typst-preview.nvim";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, nixpkgs-unstable, flake-utils, nixvim, ... }@inputs:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };

        pkgs-unstable = import nixpkgs-unstable {
          inherit system;
        };

        nixvimLib = nixvim.lib.${system};

        nixvimModule = import ./config.nix;

        nvim = nixvim.legacyPackages.${system}.makeNixvimWithModule {
          module = nixvimModule;
          extraSpecialArgs = {
            inherit inputs pkgs-unstable;
          };
        };
      in 
      {
        checks.default = nixvimLib.check.mkTestDerivationFromNixvimModule {
          module = nixvimModule;
        };

        packages.default = nvim;

        packages.neovide = pkgs.stdenv.mkDerivation {
          name = "neovide";

          phases = [ "installPhase" ];

          installPhase = ''
            mkdir -p $out/bin

            cat > $out/bin/neovide <<EOF
            #!${pkgs.runtimeShell}
            ${pkgs.neovide}/bin/neovide --neovim-bin ${nvim}/bin/nvim "\$@"
            EOF

            chmod +x $out/bin/neovide
          '';
        };
      }
    );
}